Alchemyを動かすには、Adobe の Get Start を見ればすんなりといった。amachangさんの「C/C++ のコードを Flash Player で動かす！ Alchemy を速攻試してみる。」も非常にわかりやすい。僕の場合は、Windows で Cygwin 環境でしたが同じような感じです。FlexSDK は Gumbo 使ってます。

Mersenne Twister については「Mersenne Twister with improved initialization (2002)」 のソース(mt19937ar.c)を利用しています。
比較する為に用意したクラスは、Onegameさんの記事を参考にさせていただきました。

• mersenne.c (Alchemy用Cソース)
• mersenne.swc (AlchemyででけたSWC)
• MersenneTwister.as (AS3版)
• TestAlchemy.as (テスト用AS)

とりあえず試す

今回は試してみようということで、mt19937ar.c の内、初期化の init_genrand 、乱数生成の genrand_int32 をラップしてASから使えるようにしてみる。
ラップの仕方などAlchemy的な部分は、AlchemyToolkit付属のサンプルや、ドキュメント みながら見よう見まねで。

ここは適当ながら、gccしてみるとswcがでけた。

gcc mersenne.c -swc -o mersenne.swc

さっそくASで使ってみようと。

mxmlc -library-path+=mersenne.swc --target-player=10.0.0 TestAlchemy.as

で、for文で10万回とか回しながら genrand_int32() するテストをAS3版と比較してみる。が、Alchemy版がめっぽう遅い。フリーズしたんかと思った…。どうも呼び出しにはなかなかのコストがかかる模様。

この部分は、TestAlchemy.as の test_alchemy() のところ。mersenne.c では g_int32() です。

C内でArrayつくったらどうか

乱数をひとつひとつ生成するのはあぎゃんな感じだったので、Cの方でActionScriptのArrayをつくったらパフォーマンスでるんでねーかと思ってテストしてみる。Alchemy的には、CでASのクラス生成、ASのメソッド呼び出しなところ。

TestAlchemy.as の test_alchemy_array() のところ。mersenne.c では g_int32_array() です。

結果は前と同じぐらい遅い…。CでASのメソッドを呼ぶのもコストかかってるかと…。ものによるんかも知れんけど。

だったらでByteArrayならどうなの

ArrayがダメならByteArrayってことで、C内でByteArrayに乱数を詰め込んで返すことにしてみる。

TestAlchemy.as の test_alchemy_byteArray() のところ。mersenne.c では g_int32_byteArray() です。

結果は・・・・速くなった！何かうれしい。

TestAlchemyのSWFはこれ(FlashPlayer10必要です)

まとめっぽい何か

今回試してみた印象は、AS←→C 間のやりとりに想像以上にコストかかるらしいってこと。既存のCライブラリを移植していく場合、Cで実装する分、ASに移植する分の案配がパフォーマンスにもろ影響しそう。まだリリースはされてないので今後どうなるかわからんけども。ゆくゆくパフォーマンスのいい OpenCV が使えるようになるとうれしいなぁと。

簡易版なんで、DirectLightとPointLightぐらい実装すればよいかなぁ。関係ないけどシドミードのフラット好きです。

>> Flex4 Gumbo Downloads
>> flashplayer10 reference( 070208 )
>> Gumbo Language Reference

で、Matrix3D の パフォーマンスを見たのですが、こちらは少し妙で。どうも遅い。テストは append, prepend系の行列計算を見たのですけど。テストデータが悪いのかもしれないと思える程、気持ち悪いぐらい遅い。遅いかと思ったら速いときもある…。微妙です。遅いときは自前で組んだものより50倍ぐらい遅い。謎です。遅くなる場合の条件がよくわからんのですが、気が向いたら調べるかもしれません。PV3D とか away3D の既存のライブラリは、そのまま自前の改良でいくんでしょうね。

とはいえ、Matrix3Dのメンバ関数を見ると、decompose()、recompose()、interpolate()、transformVectors()など、便利系、DisplayObjectとの整合性的なものが見られます。生っぽいMatrixのライブラリより利用するには便利なのかなぁという印象です。とりあえず簡単なサンプルをつくってみた。
※flashplayer10が必要です。

ソースはこちら。

package  
{
	import flash.events.Event;
	import flash.display.*;
	import flash.geom.*;
	
	[SWF(width=425, height=425, frameRate=60, backgroundColor=0x000000)]
	public class TestMatrix3D extends Sprite
	{
		private var particle_num:int = 3000;
		private var vertices_in:Vector.<Number>;
		private var vertices_out:Vector.<Number>;
		
		private var _matrix:Matrix3D;
		
		public function TestMatrix3D() 
		{
			//初期座標（x,y,z）と変換用のVectorつくる
			vertices_in  = new Vector.<Number>( particle_num*3, true );
			vertices_out = new Vector.<Number>( particle_num*3, true );
			
			//てきとうに座標いれとく
			for ( var i:int = 0; i < particle_num ; i+=3 )
			{
				vertices_in[i]   = Math.random() * 200 - 100;  // x
				vertices_in[i+1] = Math.random() * 200 - 100;  // y 
				vertices_in[i+2] = Math.random() * 200 - 100;  // z
			}
			
			//今回はこれのテスト
			_matrix = new Matrix3D();
			
			//中心にしとくとか
			x = stage.stageWidth/2;
			y = stage.stageHeight/2;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			
			addEventListener( Event.ENTER_FRAME, enterframe );
		}
		
		private function enterframe( e:Event ):void
		{
			//回転軸のベクトル
			//xは右、yは下、zは奥方向が正っぽい。
			var rotateAxis:Vector3D = new Vector3D( 0.2, 1.0, 0.1 );
			
			//行列に回転あてるよ。単位はラジアンでなくて度
			_matrix.appendRotation( 1, rotateAxis );
			
			//vertices_inの変換座標が、vertices_outに入るよ
			_matrix.transformVectors( vertices_in, vertices_out );
			
			//描画
			graphics.clear();
			for ( var i:int = 0; i < particle_num ; i++ )
			{
				var vx:Number = vertices_out[i]; i++;
				var vy:Number = vertices_out[i]; i++;
				var vz:Number = 400/(vertices_out[i] + 400);
				graphics.beginFill( 0xffff00 );
				graphics.drawRect( vx*vz, vy*vz, 1, 1 );
				graphics.endFill();
			}
		}
	}	
}

まぁぼちぼち。

FAdapter クラスの目的は、なにか命題的になっている「イベント処理系をいかにサクッと書くか」「リスナー書くの指だれます」といった課題に何かしらの手段を提供するものです。特にaddEventListenerとか、removeEventListenerやらが対象です。

リスナの登録

リスナの登録は以下のようにして書きます。

//対象になるEventDispatcherを指定
var adapter:FAdapter = new FAdapter(stage);

//登録
adapter.click = function( e:MouseEvent ):void
{
	trace( "test1", e.type )
};

登録はAS2のような書き方ですね。adapter.* の部分にイベントタイプを指定するわけです。書き換えるとこんな感じ。

adapter[MouseEvent.CLICK] = function( e:MouseEvent ):void
{
	trace( "test1", e.type )
};

propertyで指定するので以下のような書き方もできます。

adapter.click = adapter.mouseDown = function( e:MouseEvent ):void
{
	trace( "test1", e.type )
};

useCapture、weakReferenceなどを指定する場合は以下の通り。

//イベントタイプをメソッド名にして指定。handler以外は省略可
adapter.click( handler, capture, priority, weakReference );

//ノーマルにも書けます
adapter.addEventListener( type, handler, capture, priority, weakReference );

リスナの削除関係

リスナの削除は以下のようにして書きます。

delete adapter.click;

//あるいは
adapter.click = null;

//普通に消す場合の方法
adapter.removeEventListener("click");

//全削除
adapter.removeAll();

一応、停止と再開もできます。引数にイベントタイプを入れます。省略すると対象が全部になります。

//停止
adapter.abort("click");

//再開
adapter.resume("click");

アダプター的なところ

アダプター的なところは以下ような書き方です。

//対象はとりあえずなしでもいけます
var adapter:FAdapter = new FAdapter();
adapter.click = function( e:MouseEvent ):void
{
	trace( "test1", e.type )
};

//あとで付ける
adapter.dispatcher = stage;

補足

adapter.eventType で返されるオブジェクトは $listener(FAdapter の innerClass) です。このオブジェクトのpropertyでリスナの情報が見れます(読みのみ)。

• adapter.eventType.type
• adapter.eventType.handler
• adapter.eventType.useCapture
• adapter.eventType.priority
• adapter.eventType.useWeakReference
• adapter.eventType.active ( :Boolean abort中はfalse )

まとめみたいな

以上、全然Proxyの目的に沿ってないようですが、Proxyの動的な部分に注目して書いてみました。例外処理とか怪しいし改善点も多いですが、はじめての Proxy ということで。使いながらデバッグとか改善とかできればいいかと。一番の問題点は、当然ですが FlashDevelop などで入力補助がでないところ…です。

1.ワールドをつくる
2.BodyなDefとShapeなDefで位置とか形状をつくる
3.BodyとShapeの実体をつくる
4.計算してみる
5.表示に反映させる

ってことみたいですね(今回はJointとか衝突イベントやってないです)。「5.表示に反映させる」については、テスト用に「b2DebugDraw」というクラスがあるので、それを使えばすぐに確認できてお手軽です。
※「OOP本」はBox2Dのバージョンがわかりませんが1.x系なんでしょうか、ちょっとメソッドとか異なるようです。でも流れは同じようなので参考になります。「Box2DでActionScript物理プログラミング」のほうは 2.0.0 なのでそのままいけそうなんですが、b2World の CreateStaticBody,CreateDynamicBodyが 2.0.1 ではなくなってる様子。CreateBodyにしとけば大丈夫ぽい。

で、とりあえず試してみたかったのは、重加速度とShape属性(サイズとか)の動的変更で、その辺りはBox2Dのソースを追いながらアテを探してみることに。ソースを追うにはFlashDevelopが便利ですね。しばらく見たところ、重加速度は、b2World の m_gravity 、Shapeの属性は「3.BodyとShapeの実体をつくる」でつくったb2Shapeから辿ればいけるっぽい。感じ。

そんな流れでつくってみた、ちょっと気持ち悪いBox2Dのサンプルです。

マウスの位置で重加速度が変化して、クリックで円が増えます。で、円をsinで大きさを変えてます。ソースは以下のような感じ。

TestWorld.as

package  
{
	import Box2D.Collision.b2AABB;
	import Box2D.Common.Math.b2Vec2;
	import Box2D.Dynamics.b2World;
	import Box2D.Dynamics.b2BodyDef;
	import Box2D.Collision.Shapes.b2PolygonDef;
	import Box2D.Collision.Shapes.b2CircleDef;
	import Box2D.Dynamics.b2Body;
	import Box2D.Collision.Shapes.b2Shape;
	import Box2D.Collision.Shapes.b2CircleShape;
	import Box2D.Dynamics.b2DebugDraw;
	import flash.geom.Rectangle;
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.MouseEvent;
	
	/**
	* Box2Dなテスト
	* @author nutsu
	*/
	public class TestWorld extends MovieClip
	{
		private var world:b2World;
		
		private var WORLD_SCALE:Number = 100; // 100pixel/m
		private var VIEW_RECT:Rectangle;
		private var half_width:Number;
		private var half_height:Number;
		
		private var circles:Array;
		
		public function TestWorld() 
		{
			super();
			
			VIEW_RECT   = new Rectangle( 0, 0, stage.stageWidth/WORLD_SCALE, stage.stageHeight/WORLD_SCALE );
			half_width  = stage.stageWidth * 0.5;
			half_height = stage.stageHeight * 0.5;
			
			//動的オブジェクト用の配列 :b2CircleShape[]
			circles = [];
			
			//とりあえずワールドつくる
			initWorld();
			//静的なオブジェクト（四方壁）をつくる
			initObjects();
			//テストドローな設定
			initDraw();
			//とりあえず１こオブジェクトつくる
			addCircle( VIEW_RECT.width*0.5, VIEW_RECT.height*0.5 );
			
			addEventListener( Event.ENTER_FRAME, onEnterFrame );
			stage.addEventListener( MouseEvent.CLICK, onClick );
			
			stage.quality = "low";
		}
		
		private function initWorld():void
		{
			//物理計算エリア？　お約束らしい
			var aabb:b2AABB = new b2AABB();
			aabb.lowerBound.Set( -1000, -1000 );
			aabb.upperBound.Set( 1000, 1000 );
			
			//重加速度。後でマウス位置で変えるので０にしとく
			var gravity:b2Vec2 = new b2Vec2( 0, 0 );
			
			//力が作用してないオブジェクトをスリープするか否か。今回はずっと動いてるのでfalse
			var dosleep:Boolean = false;
			
			//ワールドつくる
			world = new b2World( aabb, gravity, dosleep );
		}
		
		private function initObjects():void
		{
			//四方壁つくる
			//大きさの単位はメートルなそうな
			var wall_size:Number = 0.025;
			
			//ShapeなDef（形状決め）
			var wall_side_shape:b2PolygonDef = new b2PolygonDef();
			wall_side_shape.SetAsBox( wall_size, VIEW_RECT.height * 0.5 );
			wall_side_shape.density = 0; //静的な物体は0なそうな
			
			var wall_vt_shape:b2PolygonDef = new b2PolygonDef();
			wall_vt_shape.SetAsBox( VIEW_RECT.width*0.5, wall_size );
			wall_vt_shape.density = 0;
			
			//BodyなDef（位置決め）
			var wall_left:b2BodyDef   = new b2BodyDef();
			var wall_right:b2BodyDef  = new b2BodyDef();
			var wall_bottom:b2BodyDef = new b2BodyDef();
			var wall_top:b2BodyDef    = new b2BodyDef();
			
			//set position
			wall_left.position.Set(  wall_size, VIEW_RECT.height * 0.5 );
			wall_right.position.Set( VIEW_RECT.width - wall_size, VIEW_RECT.height * 0.5 );
			wall_bottom.position.Set( VIEW_RECT.width * 0.5 , VIEW_RECT.height - wall_size);
			wall_top.position.Set( VIEW_RECT.width*0.5 ,  wall_size);
			
			//worldに入れてく
			world.CreateBody( wall_left   ).CreateShape( wall_side_shape );
			world.CreateBody( wall_right  ).CreateShape( wall_side_shape );
			world.CreateBody( wall_bottom ).CreateShape( wall_vt_shape );
			world.CreateBody( wall_top    ).CreateShape( wall_vt_shape );
		}
		
		private function initDraw():void
		{
			//デバッグ用のドロー設定
			var debug_draw:b2DebugDraw = new b2DebugDraw();
			debug_draw.m_sprite        = this;
			debug_draw.m_drawScale     = WORLD_SCALE;
			debug_draw.m_fillAlpha     = 1;
			debug_draw.m_lineThickness = 0;
			debug_draw.m_drawFlags     = b2DebugDraw.e_shapeBit;
			world.SetDebugDraw( debug_draw );
		}
		
		private function addCircle( ax:Number, ay:Number ):void
		{
			//任意の位置にCircleオブジェクト追加してく
			//手順　ShapeなDef→BodyなDef→worldで実体をつくる感じ
			var s:b2CircleDef = new b2CircleDef();
			s.density = 1;
			s.restitution = 0.2;
			s.radius = 0.2;
			
			var b:b2BodyDef = new b2BodyDef();
			b.position.Set( ax, ay );
			
			var bb:b2Body  = world.CreateBody( b );
			var bs:b2Shape = bb.CreateShape( s );
			bb.SetMassFromShapes();
			
			//Shapeはあとでいじるので配列にいれとく
			bs.m_userData = Number(0);
			circles.push( b2CircleShape(bs) );
		}
		
		private function onClick( e:MouseEvent ):void
		{
			addCircle(mouseX/WORLD_SCALE, mouseY/WORLD_SCALE);
		}
		
		private function onEnterFrame( e:Event ):void
		{
			if ( world )
			{
				//マウス位置で重加速度変更
				world.m_gravity.x = -2 * (half_width - mouseX) / half_width;
				world.m_gravity.y = -2 * (half_height - mouseY) / half_height;
				
				//円をうにょうにょ
				for (var i:int = 0; i < circles.length ; i++) 
				{
					var bs:b2CircleShape = circles[i];
					bs.m_radius = 0.2 + Math.sin( bs.m_userData ) * 0.1;
					bs.m_userData += 0.05;
				}
				
				//計算　Step(計算時間,計算精度)　きびっとしたいので計算時間を長めにとる
				world.Step(1/15, 4);
			}
		}
	}
}

なんと言いますか、お手軽だなぁという印象です。ライブラリって便利。

誰かに向けたメモ：
Box2Dのソースみていると、virtual があるんですが、AS に virtual ってあったんですか？自分で書いてみたらコンパイル通るみたいなんですけど、何か意味あるのかな…。

自分の環境では、translateは大体同じだけど、scale と rotate 及び影響が出ていると思われる box系で随分処理時間に差が出ています。どうでしょうか？

実際には10万回なんて実行しないので、現実的には差がないように思えますが、とりあえずメモということで。

以下実装し直した TestMatrix と 上のテストで使用したスクリプトです。

TestMatrix.as

package{
	
	import flash.geom.Matrix;
	
	public class TestMatrix extends Matrix
	{
		
		public function TestMatrix( a_:Number=1, b_:Number=0, c_:Number=0, d_:Number=1, tx_:Number=0, ty_:Number=0)
		{
			super( a_, b_, c_, d_, tx_, ty_ );
		}
		
		override public function translate( dx:Number, dy:Number ):void
		{
			//(1,0,0,1,dx,dy)
			tx += dx;
			ty += dy;
		}
		
		override public function scale( sx:Number, sy:Number ):void
		{
			//(sx,0,0,sx,0,0)
			a  *= sx;
			b  *= sy;
			c  *= sx;
			d  *= sy;
			tx *= sx;
			ty *= sy;
		}
		
		override public function rotate( angle:Number ):void
		{
			//(c, s, -s, c, 0, 0)
			var sin:Number = Math.sin(angle);
			var cos:Number = Math.cos(angle);
			var n11:Number = a * cos - b * sin;
			var n12:Number = a * sin + b * cos;
			var n21:Number = c * cos - d * sin; 
			var n22:Number = c * sin + d * cos;
			var n31:Number = tx * cos - ty * sin; 
			var n32:Number = tx * sin + ty * cos;
			a  = n11; b  = n12;
			c  = n21; d  = n22;
			tx = n31; ty = n32;
		}
	}
}

テストコード

//ベタなテストですいません
//out_txtはTextFieldです

var n:int = 50000;
var t:int;
var i:int;

var fmt:TestMatrix = new TestMatrix( 1, 2, 3, 4, 5, 6 );
var mt:Matrix = new Matrix( 1, 2, 3, 4, 5, 6 );

//---------------------------------------------
out_txt.appendText( "[SCALE]");

t = getTimer();
for( i=0; i<n; i++ )
{
	mt.scale( 10, 10 ); mt.scale( 0.1,0.1 );
}
out_txt.appendText( "\n ori: " + (getTimer()-t).toString() );

t = getTimer();
for( i=0; i<n; i++ )
{
	fmt.scale(10,10); fmt.scale(0.1,0.1);
}
out_txt.appendText( " ext: " + (getTimer()-t).toString() );

//---------------------------------------------
out_txt.appendText( "\n[TRANSLATE]");
t = getTimer();
for( i=0; i<n; i++ )
{
	mt.translate( 10, 10 ); mt.translate( -10,-10 );
}
out_txt.appendText( "\n ori: " + (getTimer()-t).toString() );

t = getTimer();
for( i=0; i<n; i++ )
{
	fmt.translate(10,10); fmt.translate(-10,-10);
}
out_txt.appendText( " ext: " + (getTimer()-t).toString() );

//---------------------------------------------
out_txt.appendText( "\n[ROTATE]");
t = getTimer();
for( i=0; i<n; i++ )
{
	mt.rotate( 1.5 ); mt.rotate( -1.5 );
}
out_txt.appendText( "\n ori: " + (getTimer()-t).toString() );

t = getTimer();
for( i=0; i<n; i++ )
{
	fmt.rotate(1.5); fmt.rotate(-1.5);
}
out_txt.appendText( " ext: " + (getTimer()-t).toString() );

//---------------------------------------------
out_txt.appendText( "\n[CREATE_BOX]");
t = getTimer();
for( i=0; i<n; i++ )
{
	mt.createBox( 10, 10, 1, 1, 1 );
	mt.createBox( 0.1, 0.1, -1, -1, -1 );
}
out_txt.appendText( "\n ori: " + (getTimer()-t).toString() );

t = getTimer();
for( i=0; i<n; i++ )
{
	fmt.createBox( 10, 10, 1, 1, 1 );
	fmt.createBox( 0.1, 0.1, -1, -1, -1 );
}
out_txt.appendText( " ext: " + (getTimer()-t).toString() );

//---------------------------------------------
out_txt.appendText( "\n[CREATE_GRADIENT_BOX]");
t = getTimer();
for( i=0; i<n; i++ )
{
	mt.createGradientBox( 10, 10, 1, 1, 1 );
	mt.createGradientBox( 0.1, 0.1, -1, -1, -1 );
}
out_txt.appendText( "\n ori: " + (getTimer()-t).toString() );

t = getTimer();
for( i=0; i<n; i++ )
{
	fmt.createGradientBox( 10, 10, 1, 1, 1 );
	fmt.createGradientBox( 0.1, 0.1, -1, -1, -1 );
}
out_txt.appendText( " ext: " + (getTimer()-t).toString() );

テストの方法が微妙な気がしますが、いいベンチマークの方法があったら知りたい…

それにしても重い…。しばらく回しているとろくろ首にみえてきた…。もっといろいろあそんでみたい。

追記
なんだか、note.xさん、MASDAさん、からリンクを張っていただいて恐縮しております。僕のサンプルは、frocessingのテストでつくってたやつなので、ソースを上げておくことにしました。以下ソースです。

package
{
	import flash.display.MovieClip;
	import flash.display.StageQuality;
	import org.libspark.thread.Thread;
	import org.libspark.thread.EnterFrameThreadExecutor;
	
	[SWF(width=425, height=600, frameRate=30, backgroundColor=0x000000)]
	public class TestPlot extends MovieClip
	{
		public function TestPlot()
		{
			stage.quality   = StageQuality.LOW;
			Thread.initialize(new EnterFrameThreadExecutor());
			new TestPlotThread(this).start();
		}
	}
}

import flash.display.Sprite;
import flash.display.Bitmap;
import flash.filters.BlurFilter;
import flash.net.URLRequest;
import flash.geom.Point;
import flash.errors.IOError;

import org.libspark.thread.Thread;
import org.libspark.thread.threads.net.URLLoaderThread;

import frocessing.core.F5BitmapData3D;
import frocessing.geom.FNumber3D;
import frocessing.math.FMath;

class TestPlotThread extends Thread
{
	private var _target:Sprite;
	private var fg:F5BitmapData3D;
	
	var w:Number = 425;
	var h:Number = 600;
	
	var dataloader:URLLoaderThread;
	var vertexs:Array;
	var colors:Array;
	
	public function TestPlotThread( target:Sprite )
	{
		_target = target;
		fg = new F5BitmapData3D( w, h, false, 0x01000000 );
		_target.addChild( new Bitmap( fg.bitmapData, "auto", true  ) );
	}
	
	override protected function run():void
	{
		var datauri:String = "1.csv";
		dataloader = new URLLoaderThread(new URLRequest(datauri))
		dataloader.start();
		dataloader.join();
		
		next(setup);
		
		error(IOError, errorHandler);
		error(SecurityError, errorHandler);
	}
	
	protected function setup():void
	{
		var dats:Array = dataloader.loader.data.split("\r\n");
		
		vertexs = [];
		colors  = [];
		var len:int = dats.length;
		var d:Array;
		var r:int;
		var g:int;
		for ( var i:int; i < len; i++ )
		{
			d = dats[i].split(",");
			r = Math.min( 0xff, (int(d[3]) + 50) );
			g = Math.min( 0xff, (int(d[3]) + 100) );
			vertexs[i] = new FNumber3D( Number(d[0]), Number(d[1]), Number(d[2]) );
			colors[i]  = r << 16 | g << 8 | 0xff;
		}
		
		fg.background( 0, 0.2 );
		fg.strokeAlpha = 0.5;
		
		next(draw);
	}
	
	var blurfilter:BlurFilter = new BlurFilter( 4 );
	var zp:Point = new Point();
	var camera_z:Number = 100;
	var _pan:Number = 0;
	var _pth:Number = 0;
	
	protected function draw():void
	{
		fg.bitmapData.applyFilter( fg.bitmapData, fg.bitmapData.rect, zp, blurfilter );
		fg.beginDraw();
		
		camera_z += ( 100 + _target.mouseY  - camera_z ) * 0.5;
		_pan += ( -FMath.radians( _target.mouseX - w/2 )*1.5 - _pan  ) * 0.2;
		_pth += ( -FMath.radians( _target.mouseY - h/2 )*0.05 - _pth ) * 0.2;
		
		fg.camera( w/2, h/2, camera_z );
		fg.translate( w/2, h/4, 0);
		
		fg.rotateY( _pan );
		fg.rotateX( _pth );
		
		var len:int = vertexs.length;
		var vt:FNumber3D;
		for ( var i:int = 0; i < len ; i++ )
		{
			fg.strokeColor = colors[i];
			vt = vertexs[i];
			fg.pixel( vt.x, vt.y, vt.z );
		}
		
		fg.endDraw();
		
		next(draw);
	}
	
	private function errorHandler(e:IOError, t:Thread):void
	{
		trace("Thread Error.");
		trace(e.getStackTrace());
		next(null);
	}
}

いい加減、きれいにソースを貼ることを考えなくちゃいけない…と思いました。

画像はPapervisionのサンプルを使わさせていただいています。（※問題あれば変えます。と誰となく)

上のサンプルのコードはこんな感じです。

import flash.display.Shape;
import flash.events.Event;
import frocessing.core.F5Graphics3D;
import frocessing.f3d.model.F3DSphere;
import frocessing.math.FMath;

var w:Number = stage.stageWidth;
var h:Number = stage.stageHeight;
var a:Number = 0;
var camera_pan:Number = 0;
var camera_pth:Number = 0;

var sp:Shape = Shape( addChild(new Shape()) );
var fg:F5Graphics3D = new F5Graphics3D( sp.graphics, w, h );

var earth:F3DSphere = new F3DSphere( 30, 12 );
earth.setTexture( new Earth(0,0) );

var bgspace:F3DSphere = new F3DSphere( 400, 12 );
bgspace.setTexture( new Space(0,0) );

stage.quality = "medium";

fg.noStroke();

function draw( e:Event ):void
{
	fg.beginDraw();
	
	camera_pan += ( FMath.radians( mouseX - w/2 ) - camera_pan )*0.2;
	camera_pth += ( FMath.radians( mouseY/2 ) - camera_pth )*0.2;
	
	var camera_x:Number = 100.0*Math.cos( camera_pan );
	var camera_y:Number = 100.0*Math.cos( camera_pth );
	var camera_z:Number = 100.0*Math.sin( camera_pan );
	fg.camera( w/2 + camera_x, h/2 + camera_y, camera_z );
	
	fg.translate(w/2, h/2, 0);
	
	fg.pushMatrix();
	fg.rotateY( -a*0.2 );
	fg.backFaceCulling = false;
	fg.model( bgspace );
	fg.popMatrix();
	
	fg.rotateY( a );
	fg.backFaceCulling = true;
	fg.model( earth );
	
	a += 0.01;
	
	fg.endDraw();
}

addEventListener( Event.ENTER_FRAME, draw );

frocessing.display.F5MovieClip3D を DocumentClass にした場合はこんな感じ。ちょと簡単に見えます。

var w:Number = fg.width;
var h:Number = fg.height;
var a:Number = 0;

var camera_pan:Number = 0;
var camera_pth:Number = 0;

var earth:F3DSphere = new F3DSphere( 30, 12 );
earth.setTexture( new Earth(0,0) );

var bgspace:F3DSphere = new F3DSphere( 400, 12 );
bgspace.setTexture( new Space(0,0) );

QMedium();
noStroke();

function draw():void
{
	camera_pan += ( radians( mouseX - w/2 ) - camera_pan )*0.2;
	camera_pth += ( radians( mouseY/2 ) - camera_pth )*0.2;
	
	var camera_x:Number = 100.0*cos( camera_pan );
	var camera_y:Number = 100.0*cos( camera_pth );
	var camera_z:Number = 100.0*sin( camera_pan );
	camera( w/2 + camera_x, h/2 + camera_y, camera_z );
	
	translate(w/2, h/2, 0);
	
	pushMatrix();
	rotateY( -a*0.2 );
	fg.backFaceCulling = false;
	model( bgspace );
	popMatrix();
	
	rotateY( a );
	fg.backFaceCulling = true;
	model( earth );
	
	a += 0.01;
}

3D関係をごにょごにょしている関係で、ソースがわりと荒れているのですが、ぼちぼち落ち着けていきたいです。あと、となりの人の意見など聞きながら、3D関連のクラス名とかメソッド名とか変わりそう。

個人的には、FBitmapGraphics や FMatrix2D.createUVBox() あたりが便利に使えるのかなぁとか思ったりしてますが、どうでしょうか。drawTriangles もどきは、F5Graphics3D.drawBitmapTriangles() あたりです。

なんだか PV3D やら Away3D やらあるから今更いいじゃないかって向きもあると思いますが、ぼちぼち楽しんでやっております。

追記：ちょっと3Dまわりを整理して、backfacecullingを入れたので若干ソースを修正しました。（2008/7/15）